Add ebuilds for x11-plugins/pidgin-opensteamworks.

1 files changed, 62 insertions, 0 deletions

diff --git a/x11-plugins/pidgin-opensteamworks/pidgin-opensteamworks-9999.ebuild b/x11-plugins/pidgin-opensteamworks/pidgin-opensteamworks-9999.ebuild
new file mode 100644
index 0000000..28bbd2e
--- /dev/null
+++ b/x11-plugins/pidgin-opensteamworks/pidgin-opensteamworks-9999.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit toolchain-funcs git-r3
+
+DESCRIPTION="Steam protocol plugin for pidgin"
+HOMEPAGE="https://github.com/eionrobb/pidgin-opensteamworks"
+EGIT_REPO_URI="git://github.com/EionRobb/${PN}.git
+	https://github.com/EionRobb/${PN}.git"
+EGIT_BOOTSTRAP=""
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gnutls"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/nss
+	gnome-base/libgnome-keyring
+	gnutls? ( net-im/pidgin[gnutls] )
+	!gnutls? ( net-im/pidgin[-gnutls] )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	virtual/pkgconfig"
+
+S=${WORKDIR}
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		tc-export CC PKG_CONFIG
+	fi
+}
+
+src_prepare() {
+	unzip "${S}"/steam-mobile/releases/icons.zip || die
+}
+
+src_configure() {
+	if use gnutls; then
+		export STEAM_CRYPT_BACKEND="gcrypt"
+	else
+		export STEAM_CRYPT_BACKEND="nss"
+	fi
+}
+
+src_compile() {
+	pushd "${S}"/steam-mobile || die
+	default
+	popd || die
+}
+
+src_install() {
+	pushd "${S}"/steam-mobile || die
+	default
+	popd || die
+	insinto /usr/share/pixmaps/pidgin/protocols
+	doins -r "${WORKDIR}"/{16,48}
+	dodoc "${S}/README.md"
+}