Add ebuilds for x11-plugins/pidgin-opensteamworks.

1 files changed, 53 insertions, 0 deletions

diff --git a/x11-plugins/pidgin-opensteamworks/pidgin-opensteamworks-1.6.1-r1.ebuild b/x11-plugins/pidgin-opensteamworks/pidgin-opensteamworks-1.6.1-r1.ebuild
new file mode 100644
index 0000000..f387955
--- /dev/null
+++ b/x11-plugins/pidgin-opensteamworks/pidgin-opensteamworks-1.6.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit toolchain-funcs
+
+DESCRIPTION="Steam protocol plugin for pidgin"
+HOMEPAGE="https://github.com/eionrobb/pidgin-opensteamworks"
+SRC_URI="https://github.com/EionRobb/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/nss
+	gnome-base/libgnome-keyring
+	net-im/pidgin[-gnutls]"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	virtual/pkgconfig"
+
+S=${WORKDIR}
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		tc-export CC PKG_CONFIG
+	fi
+}
+
+src_prepare() {
+	# see https://github.com/EionRobb/pidgin-opensteamworks/issues/40
+	cp "${FILESDIR}"/${PN}-1.3-Makefile "${S}"/${P}/steam-mobile/Makefile || die
+	unzip "${S}"/${P}/steam-mobile/releases/icons.zip || die
+}
+
+src_compile() {
+	pushd ${P}/steam-mobile || die
+	default
+	popd || die
+}
+
+src_install() {
+	pushd ${P}/steam-mobile || die
+	default
+	popd || die
+	insinto /usr/share/pixmaps/pidgin/protocols
+	doins -r "${WORKDIR}"/{16,48}
+	dodoc ${P}/README.md
+}